;+
; Name: lat_rsp_times
; 
; Purpose: Retrieve times of LAT Response (RSP) files created for date(s) specified.  RSP files are stored in 
;   LAT solar archive on hesperia.
; 
; Calling Sequence:
;   rsp_times = lat_rsp_times (date)
;    
; Input Argument:
;   date - time interval to get RSP file times for (in anytim format). 2-element range, or if scalar assumes 1 day.
;  
; Output:  Returns an array of start/end times in sec since 1/1/1979 that LAT RSP files in archive on hesperia contain
;   
; Examples:
; rsp_times = lat_rsp_times('25-feb-2014')
;  
; Kim Tolbert, Mar-2014
; Modifications: 
; 
;-

function lat_rsp_times, date
;date=['25-feb-2014','26-feb-2014']
time_range = n_elements(date) eq 1 ? anytim(date, /date_only) + [0,86400.d0] : anytim(date)
spex_find_data,'fermi_lat_rsp', time_range,  url=url

files = file_basename(url)
stime = anytim(file2time(files))
st_string = time2file(stime,/sec)
hms = ssw_strsplit(st_string,'_',/tail)
files_etime = files
for i=0,n_elements(files)-1 do files_etime[i] = repstr(files[i], '_'+hms[i],'')
etime = anytim(file2time(files_etime))
q = where(etime lt stime, count)
if count gt 0 then etime[q] = etime[q] + 86400.
return, transpose([[stime],[etime]])
end